From f8e2fc76db8e3e45218318f87105278a26bbe080 Mon Sep 17 00:00:00 2001
From: Qiyang Sun <qs2g22@soton.ac.uk>
Date: Thu, 15 Aug 2024 21:58:06 +0100
Subject: [PATCH] Add libcamera_0.3.0

libcamera_0.3.0 is modified from meta-openembedded. Eariler versions
e.g. 0.2.0 used by meta-openembedded produces a invalid pointer when
libcamera-* or rpicam-* is called. Upstreams may not update on scarthgap
branch on time.
---
 recipes-core/images/mar-image-minimal.bb      | 12 +++-
 .../libcamera/libcamera_0.3.0.bb              | 72 +++++++++++++++++++
 2 files changed, 83 insertions(+), 1 deletion(-)
 create mode 100644 recipes-multimedia/libcamera/libcamera_0.3.0.bb

diff --git a/recipes-core/images/mar-image-minimal.bb b/recipes-core/images/mar-image-minimal.bb
index 8ae5306..f1b5ef4 100644
--- a/recipes-core/images/mar-image-minimal.bb
+++ b/recipes-core/images/mar-image-minimal.bb
@@ -1,4 +1,4 @@
-SUMMARY = "A small image just capable of allowing a device to boot."
+SUMMARY = "An image just capable of the MAR project."
 
 IMAGE_INSTALL = "packagegroup-core-boot \
     packagegroup-base-extended \
@@ -14,6 +14,16 @@ IMAGE_INSTALL = "packagegroup-core-boot \
     libv4l \
     media-ctl \
     opencv \
+    ffmpeg \
+    libcamera \
+    libcamera-dev \
+    libcamera-apps \
+    gstreamer1.0 \
+    gstreamer1.0-plugins-base \
+    gstreamer1.0-plugins-good \
+    gstreamer1.0-plugins-bad \
+    gstreamer1.0-plugins-ugly \
+    gstreamer1.0-plugins-good-rpicamsrc \
     ${CORE_IMAGE_EXTRA_INSTALL}"
 
 COMPATIBLE_MACHINE = "^rpi$"
diff --git a/recipes-multimedia/libcamera/libcamera_0.3.0.bb b/recipes-multimedia/libcamera/libcamera_0.3.0.bb
new file mode 100644
index 0000000..fff4629
--- /dev/null
+++ b/recipes-multimedia/libcamera/libcamera_0.3.0.bb
@@ -0,0 +1,72 @@
+SUMMARY = "Linux libcamera framework"
+SECTION = "libs"
+
+LICENSE = "GPL-2.0-or-later & LGPL-2.1-or-later"
+
+LIC_FILES_CHKSUM = "\
+    file://LICENSES/GPL-2.0-or-later.txt;md5=fed54355545ffd980b814dab4a3b312c \
+    file://LICENSES/LGPL-2.1-or-later.txt;md5=2a4f4fd2128ea2f65047ee63fbca9f68 \
+"
+
+SRC_URI = "git://git.libcamera.org/libcamera/libcamera.git;protocol=https;branch=master"
+
+SRCREV = "aee16c06913422a0ac84ee3217f87a9795e3c2d9"
+
+PE = "1"
+
+S = "${WORKDIR}/git"
+
+DEPENDS = "python3-pyyaml-native python3-jinja2-native python3-ply-native python3-jinja2-native udev gnutls chrpath-native libevent libyaml"
+DEPENDS += "${@bb.utils.contains('DISTRO_FEATURES', 'qt', 'qtbase qtbase-native', '', d)}"
+
+PACKAGES =+ "${PN}-gst"
+
+PACKAGECONFIG ??= ""
+PACKAGECONFIG[gst] = "-Dgstreamer=enabled,-Dgstreamer=disabled,gstreamer1.0 gstreamer1.0-plugins-base"
+
+LIBCAMERA_PIPELINES ??= "auto"
+
+EXTRA_OEMESON = " \
+    -Dpipelines=${LIBCAMERA_PIPELINES} \
+    -Dv4l2=true \
+    -Dcam=enabled \
+    -Dlc-compliance=disabled \
+    -Dtest=false \
+    -Ddocumentation=disabled \
+"
+
+RDEPENDS:${PN} = "${@bb.utils.contains('DISTRO_FEATURES', 'wayland qt', 'qtwayland', '', d)}"
+
+inherit meson pkgconfig python3native
+
+do_configure:prepend() {
+    sed -i -e 's|py_compile=True,||' ${S}/utils/ipc/mojo/public/tools/mojom/mojom/generate/template_expander.py
+}
+
+do_install:append() {
+    chrpath -d ${D}${libdir}/libcamera.so
+    chrpath -d ${D}${libexecdir}/libcamera/v4l2-compat.so
+}
+
+do_package:append() {
+    bb.build.exec_func("do_package_recalculate_ipa_signatures", d)
+}
+
+do_package_recalculate_ipa_signatures() {
+    local modules
+    for module in $(find ${PKGD}/usr/lib/libcamera -name "*.so.sign"); do
+        module="${module%.sign}"
+        if [ -f "${module}" ] ; then
+            modules="${modules} ${module}"
+        fi
+    done
+
+    ${S}/src/ipa/ipa-sign-install.sh ${B}/src/ipa-priv-key.pem "${modules}"
+}
+
+FILES:${PN} += " ${libexecdir}/libcamera/v4l2-compat.so"
+FILES:${PN}-gst = "${libdir}/gstreamer-1.0"
+
+# libcamera-v4l2 explicitly sets _FILE_OFFSET_BITS=32 to get access to
+# both 32 and 64 bit file APIs.
+GLIBC_64BIT_TIME_FLAGS = ""
-- 
GitLab